{ stdenv, pkgs, fetchurl, lib, unzip, autoPatchelfHook, makeWrapper, ... }:

stdenv.mkDerivation rec {
  pname = "tal-bassline";
  version = "3.9.4";
  src = fetchurl {
    url = "https://tal-software.com/downloads/plugins/TAL-BassLine-101_64_linux.zip";
    sha256 = "sha256-J2nAoxL3XO1+k3f/sZA/K9sQ75Ivj4Vxumg2jxD1Sro=";
  };
  nativeBuildInputs = [ makeWrapper unzip autoPatchelfHook ];
  buildInputs = with pkgs; [
    freetype
    fontconfig
    alsa-lib
    pipewire
    stdenv.cc.cc.lib
  ];

  unpackPhase = ''
    unzip $src
  '';

  installPhase = ''
    mkdir -p $out/lib/vst $out/lib/vst3 $out/lib/clap
    cp -r TAL-BassLine-101/TAL-BassLine-101.clap $out/lib/clap
    cp -r TAL-BassLine-101/libTAL-BassLine-101.so $out/lib/vst
    cp -r TAL-BassLine-101/TAL-BassLine-101.vst3 $out/lib/vst3
  '';

  postFixup = ''
    for file in \
      $out/lib/clap/TAL-BassLine-101.clap \
      $out/lib/vst/libTAL-BassLine-101.so \
      $out/lib/vst3/TAL-BassLine-101.vst3/Contents/x86_64-linux/TAL-BassLine-101.so
    do
      patchelf --set-rpath "${lib.makeLibraryPath buildInputs}" $file
    done
  '';

  meta = with lib; {
    homepage = "https://tal-software.com/products/tal-bassline-101";
    description = "TAL Bassline 101";
    platforms = platforms.linux;
  };
}