music stuff

packages/rmpc-latest.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  pkg-config,
+  cmake,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rmpc";
+  version = "0.9.0";
+
+  src = fetchFromGitHub {
+    owner = "mierak";
+    repo = "rmpc";
+    rev = "master";
+    hash = "sha256-2RVP00aVtrs7F7ZJBCVoy5JL7uIR+m1AZ2HCs7pebKE=";
+  };
+
+  useFetchCargoVendor = true;
+  cargoHash = "sha256-aUvG3+PrG9xjkGyXXDE+deke4y1rbz59T/bI3+X3Khs=";
+
+  checkFlags = [
+    # Test currently broken, needs to be removed. See https://github.com/mierak/rmpc/issues/254
+    "--skip=core::scheduler::tests::interleaves_repeated_and_scheduled_jobs"
+  ];
+
+  nativeBuildInputs = [
+    installShellFiles
+    pkg-config
+    cmake
+  ];
+
+  env.VERGEN_GIT_DESCRIBE = version;
+
+  postInstall = ''
+    installManPage target/man/rmpc.1
+
+    installShellCompletion --cmd rmpc \
+      --bash target/completions/rmpc.bash \
+      --fish target/completions/rmpc.fish \
+      --zsh target/completions/_rmpc
+  '';
+
+  meta = {
+    changelog = "https://github.com/mierak/rmpc/releases/tag/${src.rev}";
+    description = "TUI music player client for MPD with album art support via kitty image protocol";
+    homepage = "https://mierak.github.io/rmpc/";
+    license = lib.licenses.bsd3;
+    longDescription = ''
+      Rusty Music Player Client is a beautiful, modern and configurable terminal-based Music Player
+      Daemon client. It was inspired by ncmpcpp and aims to provide an alternative with support for
+      album art through kitty image protocol without any ugly hacks. It also features ranger/lf
+      inspired browsing of songs and other goodies.
+    '';
+    mainProgram = "rmpc";
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+  };
+}