c7254e7bdc
+ enable lexical-scope everywhere (lexical-binding = t): ~5-10% faster startup; ~5-20% general boost + reduce consing, function calls & garbage collection by preferring cl-loop & dolist over lambda closures (for mapc[ar], add-hook, and various cl-lib filter/map/reduce functions) -- where possible + prefer functions with dedicated opcodes, like assq (see byte-defop's in bytecomp.el for more) + prefer pcase & cond (faster) over cl-case + general refactor for code readability + ensure naming & style conventions are adhered to + appease byte-compiler by marking unused variables with underscore + defer minor mode activation to after-init, emacs-startup or window-setup hooks; a customization opportunity for users + ensures custom functionality won't interfere with startup.
52 lines
1.7 KiB
EmacsLisp
52 lines
1.7 KiB
EmacsLisp
;;; core/autoload/ui.el -*- lexical-binding: t; -*-
|
|
|
|
;;;###autoload
|
|
(defun doom/toggle-fullscreen ()
|
|
"Toggle fullscreen Emacs (non-native on MacOS)."
|
|
(interactive)
|
|
(set-frame-parameter
|
|
nil 'fullscreen
|
|
(unless (frame-parameter nil 'fullscreen)
|
|
'fullboth)))
|
|
|
|
;;;###autoload
|
|
(defun doom/toggle-line-numbers (&optional arg)
|
|
"Toggle `linum-mode'."
|
|
(interactive "P")
|
|
(cond ((featurep 'nlinum)
|
|
(nlinum-mode (or arg (if nlinum-mode -1 +1))))
|
|
((featurep 'linum)
|
|
(linum-mode (or arg (if linum-mode -1 +1))))
|
|
(t
|
|
(error "No line number plugin detected"))))
|
|
|
|
;;;###autoload
|
|
(defun doom-resize-window (new-size &optional horizontal)
|
|
"Resize a window to NEW-SIZE. If HORIZONTAL, do it width-wise."
|
|
(enlarge-window (- new-size (if horizontal (window-width) (window-height)))
|
|
horizontal))
|
|
|
|
;;;###autoload
|
|
(defun doom/window-zoom ()
|
|
"Maximize and isolate the current buffer. Activate again to undo this. If the
|
|
window changes before then, the undo expires."
|
|
(interactive)
|
|
(if (and (one-window-p)
|
|
(assoc ?_ register-alist))
|
|
(jump-to-register ?_)
|
|
(window-configuration-to-register ?_)
|
|
(delete-other-windows)))
|
|
|
|
(defvar doom--window-enlargened nil)
|
|
;;;###autoload
|
|
(defun doom/window-enlargen ()
|
|
"Enlargen the current window. Activate again to undo."
|
|
(interactive)
|
|
(setq doom--window-enlargened
|
|
(if (and doom--window-enlargened
|
|
(assoc ?_ register-alist))
|
|
(ignore (jump-to-register ?_))
|
|
(window-configuration-to-register ?_)
|
|
(doom-resize-window (truncate (/ (frame-width) 1.2)) t)
|
|
(doom-resize-window (truncate (/ (frame-height) 1.2)))
|
|
t)))
|