c7254e7bdc
+ enable lexical-scope everywhere (lexical-binding = t): ~5-10% faster startup; ~5-20% general boost + reduce consing, function calls & garbage collection by preferring cl-loop & dolist over lambda closures (for mapc[ar], add-hook, and various cl-lib filter/map/reduce functions) -- where possible + prefer functions with dedicated opcodes, like assq (see byte-defop's in bytecomp.el for more) + prefer pcase & cond (faster) over cl-case + general refactor for code readability + ensure naming & style conventions are adhered to + appease byte-compiler by marking unused variables with underscore + defer minor mode activation to after-init, emacs-startup or window-setup hooks; a customization opportunity for users + ensures custom functionality won't interfere with startup.
54 lines
1.8 KiB
EmacsLisp
54 lines
1.8 KiB
EmacsLisp
;;; tools/neotree/autoload.el -*- lexical-binding: t; -*-
|
|
|
|
;;;###autoload
|
|
(defun +neotree/toggle ()
|
|
"Toggle the neotree window."
|
|
(interactive)
|
|
(let ((path buffer-file-name)
|
|
(project-root (doom-project-root)))
|
|
(require 'neotree)
|
|
(cond ((and (neo-global--window-exists-p)
|
|
(window-live-p neo-global--buffer)
|
|
(eq (current-buffer) neo-global--buffer))
|
|
(neotree-hide))
|
|
((not (and (neo-global--window-exists-p)
|
|
(equal (file-truename (neo-global--with-buffer neo-buffer--start-node))
|
|
(file-truename project-root))))
|
|
(neotree-dir project-root))
|
|
(t (neotree-find path project-root)))))
|
|
|
|
;;;###autoload
|
|
(defun +neotree/collapse-or-up ()
|
|
"Collapse an expanded directory node or go to the parent node."
|
|
(interactive)
|
|
(when-let (node (neo-buffer--get-filename-current-line))
|
|
(if (file-directory-p node)
|
|
(if (neo-buffer--expanded-node-p node)
|
|
(+neotree/collapse)
|
|
(neotree-select-up-node))
|
|
(neotree-select-up-node))))
|
|
|
|
;;;###autoload
|
|
(defun +neotree/collapse ()
|
|
"Collapse a neotree node."
|
|
(interactive)
|
|
(when-let (node (neo-buffer--get-filename-current-line))
|
|
(when (file-directory-p node)
|
|
(neo-buffer--set-expand node nil)
|
|
(neo-buffer--refresh t))
|
|
(when neo-auto-indent-point
|
|
(neo-point-auto-indent))))
|
|
|
|
;;;###autoload
|
|
(defun +neotree/expand-or-open ()
|
|
"Expand or open a neotree node."
|
|
(interactive)
|
|
(when-let (node (neo-buffer--get-filename-current-line))
|
|
(cond ((file-directory-p node)
|
|
(neo-buffer--set-expand node t)
|
|
(neo-buffer--refresh t)
|
|
(when neo-auto-indent-point
|
|
(forward-line)
|
|
(neo-point-auto-indent)))
|
|
(t
|
|
(call-interactively #'neotree-enter)))))
|