c7254e7bdc
+ enable lexical-scope everywhere (lexical-binding = t): ~5-10% faster startup; ~5-20% general boost + reduce consing, function calls & garbage collection by preferring cl-loop & dolist over lambda closures (for mapc[ar], add-hook, and various cl-lib filter/map/reduce functions) -- where possible + prefer functions with dedicated opcodes, like assq (see byte-defop's in bytecomp.el for more) + prefer pcase & cond (faster) over cl-case + general refactor for code readability + ensure naming & style conventions are adhered to + appease byte-compiler by marking unused variables with underscore + defer minor mode activation to after-init, emacs-startup or window-setup hooks; a customization opportunity for users + ensures custom functionality won't interfere with startup.
48 lines
1.4 KiB
EmacsLisp
48 lines
1.4 KiB
EmacsLisp
;;; lang/sh/autoload.el -*- lexical-binding: t; -*-
|
|
|
|
(defvar sh-extra-font-lock--keywords
|
|
`((+sh--match-var-in-double-quoted-string
|
|
(2 font-lock-variable-name-face prepend))
|
|
(,(concat
|
|
"\\<"
|
|
(regexp-opt '("sudo" "echo" "ls" "sleep" "tee" "cd" "cat" "service"))
|
|
"\\>")
|
|
(0 'font-lock-builtin-face))))
|
|
|
|
;;;###autoload
|
|
(defun +sh--in-double-quoted-string-p ()
|
|
"Non-nil if point in inside a double-quoted string."
|
|
(eq (nth 3 (syntax-ppss)) ?\"))
|
|
|
|
;;;###autoload
|
|
(defun +sh--match-var-in-double-quoted-string (limit)
|
|
"Search for variables in double-quoted strings bounded by LIMIT."
|
|
(let (res)
|
|
(while
|
|
(and (setq res
|
|
(re-search-forward
|
|
"\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\)"
|
|
limit t))
|
|
(not (+sh--in-double-quoted-string-p))))
|
|
res))
|
|
|
|
;;;###autoload
|
|
(defun +sh|extra-fontify ()
|
|
"Activate sh-extra-font-lock."
|
|
(interactive)
|
|
(font-lock-add-keywords nil sh-extra-font-lock--keywords)
|
|
(if (fboundp 'font-lock-flush)
|
|
(font-lock-flush)
|
|
(when font-lock-mode
|
|
(with-no-warnings
|
|
(font-lock-fontify-buffer)))))
|
|
|
|
(defvar sh-shell-file)
|
|
;;;###autoload
|
|
(defun +sh/repl ()
|
|
"Open a shell REPL."
|
|
(let* ((dest-sh (symbol-name sh-shell))
|
|
(sh-shell-file dest-sh))
|
|
(sh-shell-process t)
|
|
(with-current-buffer "*shell*"
|
|
(rename-buffer (format "*shell [%s]*" dest-sh)))))
|