ad6a3d0f33
featurep! will be renamed modulep! in the future, so it's been deprecated. They have identical interfaces, and can be replaced without issue. featurep! was never quite the right name for this macro. It implied that it had some connection to featurep, which it doesn't (only that it was similar in purpose; still, Doom modules are not features). To undo such implications and be consistent with its namespace (and since we're heading into a storm of breaking changes with the v3 release anyway), now was the best opportunity to begin the transition.
75 lines
3 KiB
EmacsLisp
75 lines
3 KiB
EmacsLisp
;;; tools/lsp/autoload/lsp-mode.el -*- lexical-binding: t; -*-
|
|
;;;###if (not (modulep! +eglot))
|
|
|
|
;;;###autodef
|
|
(defun set-lsp-priority! (client priority)
|
|
"Change the PRIORITY of lsp CLIENT."
|
|
(require 'lsp-mode)
|
|
(if-let (client (gethash client lsp-clients))
|
|
(setf (lsp--client-priority client)
|
|
priority)
|
|
(error "No LSP client named %S" client)))
|
|
|
|
;;;###autoload
|
|
(defun +lsp/uninstall-server (dir)
|
|
"Delete a LSP server from `lsp-server-install-dir'."
|
|
(interactive
|
|
(list (read-directory-name "Uninstall LSP server: " lsp-server-install-dir nil t)))
|
|
(unless (file-directory-p dir)
|
|
(user-error "Couldn't find %S directory" dir))
|
|
(delete-directory dir 'recursive)
|
|
(message "Uninstalled %S" (file-name-nondirectory dir)))
|
|
|
|
;;;###autoload
|
|
(defun +lsp/switch-client (client)
|
|
"Switch to another LSP server."
|
|
(interactive
|
|
(progn
|
|
(require 'lsp-mode)
|
|
(list (completing-read
|
|
"Select server: "
|
|
(or (mapcar #'lsp--client-server-id (lsp--filter-clients (-andfn #'lsp--supports-buffer?
|
|
#'lsp--server-binary-present?)))
|
|
(user-error "No available LSP clients for %S" major-mode))))))
|
|
(require 'lsp-mode)
|
|
(let* ((client (if (symbolp client) client (intern client)))
|
|
(match (car (lsp--filter-clients (lambda (c) (eq (lsp--client-server-id c) client)))))
|
|
(workspaces (lsp-workspaces)))
|
|
(unless match
|
|
(user-error "Couldn't find an LSP client named %S" client))
|
|
(let ((old-priority (lsp--client-priority match)))
|
|
(setf (lsp--client-priority match) 9999)
|
|
(unwind-protect
|
|
(if workspaces
|
|
(lsp-workspace-restart
|
|
(if (cdr workspaces)
|
|
(lsp--completing-read "Select server: "
|
|
workspaces
|
|
'lsp--workspace-print
|
|
nil t)
|
|
(car workspaces)))
|
|
(lsp-mode +1))
|
|
(add-transient-hook! 'lsp-after-initialize-hook
|
|
(setf (lsp--client-priority match) old-priority))))))
|
|
|
|
;;;###autoload
|
|
(defun +lsp-lookup-definition-handler ()
|
|
"Find definition of the symbol at point using LSP."
|
|
(interactive)
|
|
(when-let (loc (lsp-request "textDocument/definition"
|
|
(lsp--text-document-position-params)))
|
|
(lsp-show-xrefs (lsp--locations-to-xref-items loc) nil nil)
|
|
'deferred))
|
|
|
|
;;;###autoload
|
|
(defun +lsp-lookup-references-handler (&optional include-declaration)
|
|
"Find project-wide references of the symbol at point using LSP."
|
|
(interactive "P")
|
|
(when-let
|
|
(loc (lsp-request "textDocument/references"
|
|
(append (lsp--text-document-position-params)
|
|
(list
|
|
:context `(:includeDeclaration
|
|
,(lsp-json-bool include-declaration))))))
|
|
(lsp-show-xrefs (lsp--locations-to-xref-items loc) nil t)
|
|
'deferred))
|