55 lines
2 KiB
EmacsLisp
55 lines
2 KiB
EmacsLisp
;;; ui/pretty-code/settings.el -*- lexical-binding: t; -*-
|
|
|
|
;;;###autoload
|
|
(defvar +pretty-code-symbols-alist '((t))
|
|
"An alist containing a mapping of major modes to its value for
|
|
`prettify-symbols-alist'.")
|
|
|
|
;;;###autodef
|
|
(defun set-pretty-symbols! (modes &rest plist)
|
|
"Associates string patterns with icons in certain major-modes.
|
|
|
|
MODES is a major mode symbol or a list of them.
|
|
PLIST is a property list whose keys must match keys in `+pretty-code-symbols',
|
|
and whose values are strings representing the text to be replaced with that
|
|
symbol. If the car of PLIST is nil, then unset any pretty symbols previously
|
|
defined for MODES.
|
|
|
|
The following properties are special:
|
|
|
|
:alist ALIST
|
|
Appends ALIST to `prettify-symbols-alist' literally, without mapping text to
|
|
`+pretty-code-symbols'.
|
|
:merge BOOL
|
|
If non-nil, merge with previously defined `prettify-symbols-alist',
|
|
otherwise overwrite it.
|
|
|
|
For example, the rule for emacs-lisp-mode is very simple:
|
|
|
|
(set-pretty-symbols! 'emacs-lisp-mode
|
|
:lambda \"lambda\")
|
|
|
|
This will replace any instances of \"lambda\" in emacs-lisp-mode with the symbol
|
|
assicated with :lambda in `+pretty-code-symbols'.
|
|
|
|
Pretty symbols can be unset for emacs-lisp-mode with:
|
|
|
|
(set-pretty-symbols! 'emacs-lisp-mode nil)"
|
|
(declare (indent defun))
|
|
(if (null (car-safe plist))
|
|
(dolist (mode (doom-enlist modes))
|
|
(delq (assq mode +pretty-code-symbols-alist)
|
|
+pretty-code-symbols-alist))
|
|
(let (results merge key)
|
|
(while plist
|
|
(pcase (setq key (pop plist))
|
|
(:merge (setq merge (pop plist)))
|
|
(:alist (setq results (append (pop plist) results)))
|
|
(_
|
|
(when-let (char (plist-get +pretty-code-symbols key))
|
|
(push (cons (pop plist) char) results)))))
|
|
(dolist (mode (doom-enlist modes))
|
|
(unless merge
|
|
(delq (assq mode +pretty-code-symbols-alist)
|
|
+pretty-code-symbols-alist))
|
|
(push (cons mode results) +pretty-code-symbols-alist)))))
|