77e4cc4d58
:feature was a "catch-all" category. Many of its modules fit better in other categories, so they've been moved: - feature/debugger -> tools/debugger - feature/evil -> editor/evil - feature/eval -> tools/eval - feature/lookup -> tools/lookup - feature/snippets -> editor/snippets - feature/file-templates -> editor/file-templates - feature/workspaces -> ui/workspaces More potential changes in the future: - A new :term category for terminal emulation modules (eshell, term and vterm). - A new :os category for modules dedicated to os-specific functionality. The :tools macos module would fit here, but so would modules for nixos and arch. - A new :services category for web-service integration, like wakatime, twitter, elfeed, gist and pastebin services.
74 lines
2.8 KiB
EmacsLisp
74 lines
2.8 KiB
EmacsLisp
;;; editor/multiple-cursors/autoload/evil-mc.el -*- lexical-binding: t; -*-
|
|
;;;###if (featurep! :editor evil)
|
|
|
|
;;;###autoload
|
|
(defun +multiple-cursors/evil-mc-toggle-cursors ()
|
|
"Toggle frozen state of evil-mc cursors."
|
|
(interactive)
|
|
(setq evil-mc-frozen (not (and (evil-mc-has-cursors-p)
|
|
evil-mc-frozen)))
|
|
(if evil-mc-frozen
|
|
(message "evil-mc paused")
|
|
(message "evil-mc resumed")))
|
|
|
|
;;;###autoload (autoload '+multiple-cursors/evil-mc-make-cursor-here "editor/multiple-cursors/autoload/evil-mc" nil t)
|
|
(evil-define-command +multiple-cursors/evil-mc-make-cursor-here ()
|
|
"Create a cursor at point. If in visual block or line mode, then create
|
|
cursors on each line of the selection, on the column of the cursor. Otherwise
|
|
pauses cursors."
|
|
:repeat nil
|
|
:keep-visual nil
|
|
:evil-mc t
|
|
(interactive)
|
|
(cond ((memq evil-this-type '(block line))
|
|
(let ((col (evil-column))
|
|
(line-at-pt (line-number-at-pos)))
|
|
;; Fix off-by-one error
|
|
(when (= evil-visual-direction 1)
|
|
(cl-decf col)
|
|
(backward-char))
|
|
(save-excursion
|
|
(evil-apply-on-block
|
|
(lambda (ibeg _)
|
|
(unless (= line-at-pt (line-number-at-pos ibeg))
|
|
(goto-char ibeg)
|
|
(move-to-column col)
|
|
(when (= (current-column) col)
|
|
(evil-mc-make-cursor-here))))
|
|
evil-visual-beginning
|
|
(if (eq evil-this-type 'line) (1- evil-visual-end) evil-visual-end)
|
|
nil)
|
|
(evil-exit-visual-state))))
|
|
(t
|
|
(evil-mc-pause-cursors)
|
|
;; I assume I don't want the cursors to move yet
|
|
(evil-mc-make-cursor-here))))
|
|
|
|
;;;###autoload (autoload '+multiple-cursors:evil-mc "editor/multiple-cursors/autoload/evil-mc" nil t)
|
|
(evil-define-command +multiple-cursors:evil-mc (beg end type pattern &optional bang)
|
|
"Create mc cursors at each match of PATTERN within BEG and END, and leave the
|
|
cursor at the final match. If BANG, then treat PATTERN as literal."
|
|
:move-point nil
|
|
:evil-mc t
|
|
(interactive "<R><//g><!>")
|
|
(unless (and (stringp pattern)
|
|
(not (string-empty-p pattern)))
|
|
(user-error "A regexp pattern is required"))
|
|
(require 'evil-mc)
|
|
(setq evil-mc-pattern
|
|
(cons (evil-ex-make-search-pattern
|
|
(if bang (regexp-quote pattern) pattern))
|
|
(list beg end type)))
|
|
(save-excursion
|
|
(evil-with-restriction beg end
|
|
(evil-mc-make-cursors-for-all)))
|
|
(evil-exit-visual-state)
|
|
(evil-mc-goto-cursor
|
|
(if (= (evil-visual-direction) 1)
|
|
(evil-mc-find-last-cursor)
|
|
(evil-mc-find-first-cursor))
|
|
nil)
|
|
(evil-mc-undo-cursor-at-pos (point))
|
|
(if (evil-mc-has-cursors-p)
|
|
(evil-mc-print-cursors-info "Created")
|
|
(evil-mc-message "No cursors were created")))
|