Move :tools neotree => :ui neotree

modules/ui/neotree/README.org

@@ -0,0 +1,9 @@
+#+TITLE: :evil neotree
+
+This module brings a side panel for browsing project files, inspired by vim's
+NERDTree.
+
+#+begin_quote
+Sure, there's dired and projectile, but sometimes I'd like a bird's eye view of
+a project.
+#+end_quote

modules/ui/neotree/autoload.el

@@ -0,0 +1,70 @@
+;;; ui/neotree/autoload.el -*- lexical-binding: t; -*-
+
+;; `neotree-show' and `neotree-find' don't respect the current project, and open
+;; neotree in `default-directory'. `+neotree/open' and `neotree/find-this-file'
+;; will ensure the neotree pane is always rooted in the project root.
+
+;;;###autoload
+(defun +neotree/open ()
+  "Open the neotree window in the current project."
+  (interactive)
+  (let ((project-root (doom-project-root 'nocache)))
+    (require 'neotree)
+    (if (neo-global--window-exists-p)
+        (neotree-hide)
+      (neotree-dir project-root))))
+
+;;;###autoload
+(defun +neotree/find-this-file ()
+  "Open the neotree window in the current project, and find the current file."
+  (interactive)
+  (let ((path buffer-file-name)
+        (project-root (doom-project-root 'nocache)))
+    (require 'neotree)
+    (cond ((and (neo-global--window-exists-p)
+                (get-buffer-window neo-buffer-name t))
+           (neotree-find path project-root)
+           (neotree-refresh))
+          ((not (and (neo-global--window-exists-p)
+                     (equal (file-truename (neo-global--with-buffer neo-buffer--start-node))
+                            (file-truename project-root))))
+           (neotree-dir project-root)
+           (neotree-find path project-root))
+          (t
+           (neotree-find path project-root)))))
+
+;;;###autoload
+(defun +neotree/collapse-or-up ()
+  "Collapse an expanded directory node or go to the parent node."
+  (interactive)
+  (when-let* ((node (neo-buffer--get-filename-current-line)))
+    (if (file-directory-p node)
+        (if (neo-buffer--expanded-node-p node)
+            (+neotree/collapse)
+          (neotree-select-up-node))
+      (neotree-select-up-node))))
+
+;;;###autoload
+(defun +neotree/collapse ()
+  "Collapse a neotree node."
+  (interactive)
+  (when-let* ((node (neo-buffer--get-filename-current-line)))
+    (when (file-directory-p node)
+      (neo-buffer--set-expand node nil)
+      (neo-buffer--refresh t))
+    (when neo-auto-indent-point
+      (neo-point-auto-indent))))
+
+;;;###autoload
+(defun +neotree/expand-or-open ()
+  "Expand or open a neotree node."
+  (interactive)
+  (when-let* ((node (neo-buffer--get-filename-current-line)))
+    (cond ((file-directory-p node)
+           (neo-buffer--set-expand node t)
+           (neo-buffer--refresh t)
+           (when neo-auto-indent-point
+             (forward-line)
+             (neo-point-auto-indent)))
+          (t
+           (call-interactively #'neotree-enter)))))

modules/ui/neotree/config.el

@@ -0,0 +1,56 @@
+;;; ui/neotree/config.el -*- lexical-binding: t; -*-
+
+(def-package! neotree
+  :commands (neotree-show
+             neotree-hide
+             neotree-toggle
+             neotree-dir
+             neotree-find
+             neo-global--with-buffer
+             neo-global--window-exists-p)
+  :config
+  (setq neo-create-file-auto-open nil
+        neo-auto-indent-point nil
+        neo-autorefresh nil
+        neo-mode-line-type 'none
+        neo-window-width 28
+        neo-show-updir-line nil
+        neo-theme 'nerd ; fallback
+        neo-banner-message nil
+        neo-confirm-create-file #'off-p
+        neo-confirm-create-directory #'off-p
+        neo-show-hidden-files nil
+        neo-keymap-style 'concise
+        neo-show-hidden-files t
+        neo-hidden-regexp-list
+        '(;; vcs folders
+          "^\\.\\(git\\|hg\\|svn\\)$"
+          ;; compiled files
+          "\\.\\(pyc\\|o\\|elc\\|lock\\|css.map\\)$"
+          ;; generated files, caches or local pkgs
+          "^\\(node_modules\\|vendor\\|.\\(project\\|cask\\|yardoc\\|sass-cache\\)\\)$"
+          ;; org-mode folders
+          "^\\.\\(sync\\|export\\|attach\\)$"
+          "~$"
+          "^#.*#$"))
+
+  (set! :popup "^ ?\\*NeoTree"
+    `((side . ,neo-window-position) (size . ,neo-window-width))
+    '((quit . current) (select . t)))
+
+  (when (bound-and-true-p winner-mode)
+    (push neo-buffer-name winner-boring-buffers))
+
+  ;; The cursor always sits at bol. `+neotree*fix-cursor' and
+  ;; `+neotree*indent-cursor' change that behavior, so that the cursor is always
+  ;; on the first non-blank character on the line, in the neo buffer.
+  (defun +neotree*fix-cursor (&rest _)
+    (with-current-buffer neo-global--buffer
+      (+neotree*indent-cursor)))
+  (add-hook 'neo-enter-hook #'+neotree*fix-cursor)
+
+  (defun +neotree*indent-cursor (&rest _)
+    (beginning-of-line)
+    (skip-chars-forward " \t\r"))
+  (advice-add #'neotree-next-line :after #'+neotree*indent-cursor)
+  (advice-add #'neotree-previous-line :after #'+neotree*indent-cursor))

modules/ui/neotree/packages.el

@@ -0,0 +1,4 @@
+;; -*- no-byte-compile: t; -*-
+;;; ui/neotree/packages.el
+
+(package! neotree)