💥 Remove :feature category

:feature was a "catch-all" category. Many of its modules fit better in
other categories, so they've been moved:

- feature/debugger -> tools/debugger
- feature/evil -> editor/evil
- feature/eval -> tools/eval
- feature/lookup -> tools/lookup
- feature/snippets -> editor/snippets
- feature/file-templates -> editor/file-templates
- feature/workspaces -> ui/workspaces

More potential changes in the future:

- A new :term category for terminal emulation modules (eshell, term and
  vterm).
- A new :os category for modules dedicated to os-specific functionality.
  The :tools macos module would fit here, but so would modules for nixos
  and arch.
- A new :services category for web-service integration, like wakatime,
  twitter, elfeed, gist and pastebin services.

modules/tools/eval/autoload/eval.el

@@ -0,0 +1,49 @@
+;;; tools/eval/autoload/eval.el -*- lexical-binding: t; -*-
+
+;;;###autoload
+(defun +eval/buffer ()
+  "Evaluate the whole buffer."
+  (interactive)
+  (cond ((assq major-mode +eval-runners)
+         (+eval/region (point-min) (point-max)))
+        (t (quickrun))))
+
+;;;###autoload
+(defun +eval/region (beg end)
+  "Evaluate a region between BEG and END and display the output."
+  (interactive "r")
+  (let ((load-file-name buffer-file-name))
+    (if-let* ((runner (cdr (assq major-mode +eval-runners))))
+        (funcall runner beg end)
+      (quickrun-region beg end))))
+
+;;;###autoload
+(defun +eval/line-or-region ()
+  "Evaluate the current line or selected region."
+  (interactive)
+  (if (use-region-p)
+      (call-interactively #'+eval/region)
+    (+eval/region (line-beginning-position) (line-end-position))))
+
+;;;###autoload
+(defun +eval/buffer-or-region ()
+  "Evaluate the whole buffer."
+  (interactive)
+  (call-interactively
+   (if (use-region-p)
+       #'+eval/region
+     #'+eval/buffer)))
+
+;;;###autoload
+(defun +eval/region-and-replace (beg end)
+  "Evaluation a region between BEG and END, and replace it with the result."
+  (interactive "r")
+  (cond ((eq major-mode 'emacs-lisp-mode)
+         (kill-region beg end)
+         (condition-case nil
+             (prin1 (eval (read (current-kill 0)))
+                    (current-buffer))
+           (error (message "Invalid expression")
+                  (insert (current-kill 0)))))
+        (t (quickrun-replace-region beg end))))
+

modules/tools/eval/autoload/evil.el

@@ -0,0 +1,23 @@
+;; tools/eval/autoload/evil.el -*- lexical-binding: t; -*-
+;;;###if (featurep! :editor evil)
+
+;;;###autoload (autoload '+eval:region "tools/eval/autoload/evil" nil t)
+(evil-define-operator +eval:region (beg end)
+  "Send region to the currently open repl, if available."
+  :move-point nil
+  (interactive "<r>")
+  (+eval/region beg end))
+
+;;;###autoload (autoload '+eval:replace-region "tools/eval/autoload/evil" nil t)
+(evil-define-operator +eval:replace-region (beg end)
+  :move-point nil
+  (interactive "<r>")
+  (+eval/region-and-replace beg end))
+
+;;;###autoload (autoload '+eval:repl "tools/eval/autoload/evil" nil t)
+(evil-define-operator +eval:repl (beg end &optional bang)
+  :move-point nil
+  (interactive "<r><!>")
+  (if (evil-normal-state-p)
+      (+eval/open-repl-other-window bang)
+    (+eval/send-region-to-repl beg end bang)))

modules/tools/eval/autoload/repl.el

@@ -0,0 +1,102 @@
+;;; tools/eval/autoload/repl.el -*- lexical-binding: t; -*-
+
+(defvar +eval-repl-buffers (make-hash-table :test 'equal)
+  "The buffer of the last open repl.")
+
+(define-minor-mode +eval-repl-mode
+  "A minor mode for REPL buffers.")
+
+(defun +eval--ensure-in-repl-buffer (&optional command other-window-p)
+  (maphash (lambda (key buffer)
+             (unless (buffer-live-p buffer)
+               (remhash key +eval-repl-buffers)))
+           +eval-repl-buffers)
+  (let* ((project-root (doom-project-root))
+         (key (cons major-mode project-root))
+         (buffer (gethash key +eval-repl-buffers)))
+    (cl-check-type buffer (or buffer null))
+    (unless (eq buffer (current-buffer))
+      (funcall (if other-window-p #'pop-to-buffer #'switch-to-buffer)
+               (if (buffer-live-p buffer)
+                   buffer
+                 (setq buffer
+                       (save-window-excursion
+                         (if (commandp command)
+                             (call-interactively command)
+                           (funcall command))))
+                 (cond ((null buffer)
+                        (error "REPL handler %S couldn't open the REPL buffer" command))
+                       ((not (bufferp buffer))
+                        (error "REPL handler %S failed to return a buffer" command)))
+                 (with-current-buffer buffer
+                   (+eval-repl-mode +1))
+                 (puthash key buffer +eval-repl-buffers)
+                 buffer)))
+    (with-current-buffer buffer
+      (goto-char (if (and (derived-mode-p 'comint-mode)
+                          (cdr comint-last-prompt))
+                     (cdr comint-last-prompt)
+                   (point-max)))
+      buffer)))
+
+(defun +eval-open-repl (prompt-p &optional other-window-p)
+  (let ((command (cdr (assq major-mode +eval-repls))))
+    (when (or (not command) prompt-p)
+      (let* ((choices (or (cl-loop for sym being the symbols
+                                   for sym-name = (symbol-name sym)
+                                   if (string-match "^\\(?:\\+\\)?\\([^/]+\\)/open-\\(?:\\(.+\\)-\\)?repl$" sym-name)
+                                   collect
+                                   (format "%s (%s)"
+                                           (match-string-no-properties 1 sym-name)
+                                           (or (match-string-no-properties 2 sym-name) "default")))
+                          (user-error "There are no known available REPLs")))
+             (choice (or (completing-read "Open a REPL for: " choices)
+                         (user-error "Aborting")))
+             (choice-split (split-string choice " " t))
+             (module (car choice-split))
+             (repl (substring (cadr choice-split) 1 -1)))
+        (setq command
+              (intern-soft
+               (format "+%s/open-%srepl" module
+                       (if (string= repl "default")
+                           ""
+                         repl))))))
+    (unless (commandp command)
+      (error "Couldn't find a valid REPL for %s" major-mode))
+    (when (+eval--ensure-in-repl-buffer command other-window-p)
+      (when (bound-and-true-p evil-mode)
+        (call-interactively #'evil-append-line))
+      t)))
+
+;;;###autoload
+(defun +eval/open-repl-same-window (&optional arg)
+  "Opens (or reopens) the REPL associated with the current major-mode and place
+the cursor at the prompt.
+
+If ARG (universal argument), prompt for a specific REPL to open."
+  (interactive "P")
+  (+eval-open-repl arg))
+
+;;;###autoload
+(defun +eval/open-repl-other-window (&optional arg)
+  "Does `+eval/open-repl', but in a popup window.
+
+If ARG (universal argument), prompt for a specific REPL to open."
+  (interactive "P")
+  (+eval-open-repl arg t))
+
+;;;###autoload
+(defun +eval/send-region-to-repl (beg end &optional auto-execute-p)
+  "REPL must be open! Sends a selected region to it. If AUTO-EXECUTE-P, then
+execute it immediately after."
+  (interactive "r")
+  (let ((selection (buffer-substring-no-properties beg end)))
+    (unless (+eval--ensure-in-repl-buffer)
+      (error "No REPL open"))
+    (when (bound-and-true-p evil-mode)
+      (call-interactively #'evil-append-line))
+    (insert (string-trim selection))
+    (when auto-execute-p
+      ;; I don't use `comint-send-input' because different REPLs may have their
+      ;; own. So I just emulate the keypress.
+      (execute-kbd-macro (kbd "RET")))))

modules/tools/eval/autoload/settings.el

@@ -0,0 +1,58 @@
+;;; tools/eval/autoload/settings.el -*- lexical-binding: t; -*-
+
+;;
+;; REPLs
+
+;;;###autoload
+(defvar +eval-repls nil
+  "An alist mapping major modes to plists that describe REPLs. Used by
+`+eval/open-repl-other-window' and filled with the `:repl' setting.")
+
+;;;###autodef
+(defun set-repl-handler! (modes command)
+  "Defines a REPL for MODES.
+
+MODES is either a single major mode symbol or a list of them. COMMAND is a
+function that creates and returns the REPL buffer.
+
+COMMAND can either be a function that takes no arguments, or an interactive
+command that will be called interactively."
+  (dolist (mode (doom-enlist modes))
+    (setf (alist-get mode +eval-repls) command)))
+
+
+;;
+;; Evaluation
+
+;;;###autoload
+(defvar +eval-runners nil
+  "Alist mapping major modes to interactive runner functions.")
+
+;;;###autodef
+(defun set-eval-handler! (mode command)
+  "Define a code evaluator for major mode MODE with `quickrun'.
+
+1. If MODE is a string and COMMAND is the string, MODE is a file regexp and
+   COMMAND is a string key for an entry in `quickrun-file-alist'.
+2. If MODE is not a string and COMMAND is a string, MODE is a major-mode symbol
+   and COMMAND is a key (for `quickrun--language-alist'), and will be registered
+   in `quickrun--major-mode-alist'.
+3. If MODE is not a string and COMMAND is an alist, see `quickrun-add-command':
+   (quickrun-add-command MODE COMMAND :mode MODE).
+4. If MODE is not a string and COMMANd is a symbol, add it to
+   `+eval-runners', which is used by `+eval/region'."
+  (declare (indent defun))
+  (cond ((symbolp command)
+         (push (cons mode command) +eval-runners))
+        ((stringp command)
+         (after! quickrun
+           (push (cons mode command)
+                 (if (stringp mode)
+                     quickrun-file-alist
+                   quickrun--major-mode-alist))))
+        ((listp command)
+         (after! quickrun
+           (quickrun-add-command
+             (or (cdr (assq mode quickrun--major-mode-alist))
+                 (string-remove-suffix "-mode" (symbol-name mode)))
+             command :mode mode)))))