feature/version-control => ui/vc-gutter, emacs/vc

Reorganize vcs functionality. Moves the custom fringe bitmaps into :ui
vc-gutter.

modules/emacs/vc/autoload.el

@@ -0,0 +1,52 @@
+;;; emacs/vc/autoload.el -*- lexical-binding: t; -*-
+
+;;;###autoload
+(defun +vc-git-root-url ()
+  "Return the root git repo URL for the current file."
+  (require 'git-link)
+  (let* ((remote (git-link--select-remote))
+         (remote-url (git-link--remote-url remote))
+         (remote-info (if remote-url (git-link--parse-remote remote-url))))
+    (if remote-info
+        (format "https://%s/%s" (car remote-info) (cadr remote-info))
+      (error  "Remote `%s' is unknown or contains an unsupported URL" remote))))
+
+(defvar git-link-open-in-browser)
+;;;###autoload
+(defun +vc/git-browse ()
+  "Open the website for the current version controlled file. Fallback to
+repository root."
+  (interactive)
+  (require 'git-link)
+  (cl-destructuring-bind (beg end)
+      (if buffer-file-name (git-link--get-region))
+    (let ((git-link-open-in-browser t))
+      (git-link (git-link--select-remote) beg end))))
+
+;;;###autoload
+(defun +vc/git-browse-issues ()
+  "Open the issues page for current repo."
+  (interactive)
+  (browse-url (format "%s/issues" (+vc-git-root-url))))
+
+;;;###autoload
+(defun +vc/git-browse-pulls ()
+  "Open the pull requests page for current repo."
+  (interactive)
+  (browse-url (format "%s/pulls" (+vc-git-root-url))))
+
+;;;###autoload
+(defun +vc*update-header-line (revision)
+  "Show revision details in the header-line, instead of the minibuffer.
+
+Sometimes I forget `git-timemachine' is enabled in a buffer. Putting revision
+info in the `header-line-format' is a good indication."
+  (let* ((date-relative (nth 3 revision))
+         (date-full (nth 4 revision))
+         (author (if git-timemachine-show-author (concat (nth 6 revision) ": ") ""))
+         (sha-or-subject (if (eq git-timemachine-minibuffer-detail 'commit) (car revision) (nth 5 revision))))
+    (setq header-line-format
+          (format "%s%s [%s (%s)]"
+                  (propertize author 'face 'git-timemachine-minibuffer-author-face)
+                  (propertize sha-or-subject 'face 'git-timemachine-minibuffer-detail-face)
+                  date-full date-relative))))

modules/emacs/vc/config.el

@@ -0,0 +1,105 @@
+;;; emacs/vc/config.el -*- lexical-binding: t; -*-
+
+(defvar +vc-auto-hydra-smerge t
+  "When entering `smerge-mode' automatically open associated hydra.")
+
+
+;;
+;; Plugins
+;;
+
+;; `git-timemachine'
+(after! git-timemachine
+  ;; Sometimes I forget `git-timemachine' is enabled in a buffer, so instead of
+  ;; showing revision details in the minibuffer, show them in
+  ;; `header-line-format', which has better visibility.
+  (setq git-timemachine-show-minibuffer-details t)
+  (advice-add #'git-timemachine--show-minibuffer-details :override #'+vc*update-header-line)
+
+  (after! evil
+    ;; Force evil to rehash keybindings for the current state
+    (add-hook 'git-timemachine-mode-hook #'evil-normalize-keymaps)))
+
+
+;; `git-commit-mode'
+;; see https://chris.beams.io/posts/git-commit/
+(setq git-commit-fill-column 72
+      git-commit-summary-max-length 50
+      git-commit-style-convention-checks '(overlong-summary-line non-empty-second-line))
+(when (featurep! :feature evil)
+  (add-hook 'git-commit-mode-hook #'evil-insert-state))
+
+
+;;
+;; `vc'
+;;
+
+;; `vc-hooks'
+(setq vc-make-backup-files nil)
+
+;; `vc-annotate'
+(after! vc-annotate
+  (set-popup-rules!
+    '(("^\\vc-d" :select nil)     ; *vc-diff*
+      ("^\\vc-c" :select t))) ; *vc-change-log*
+  (set-evil-initial-state!
+    '(vc-annotate-mode vc-git-log-view-mode)
+    'normal))
+
+;; `smerge-mode'
+(defun +vcs|enable-smerge-mode-maybe ()
+  "Auto-enable `smerge-mode' when merge conflict is detected."
+  (save-excursion
+    (goto-char (point-min))
+    (when (re-search-forward "^<<<<<<< " nil :noerror)
+      (smerge-mode 1)
+      (when (and (featurep 'hydra) +vc-auto-hydra-smerge)
+        (+hydra-smerge/body)))))
+(add-hook 'find-file-hook #'+vcs|enable-smerge-mode-maybe)
+
+(after! smerge-mode ; built-in
+  (unless EMACS26+
+    (with-no-warnings
+      (defalias #'smerge-keep-upper #'smerge-keep-mine)
+      (defalias #'smerge-keep-lower #'smerge-keep-other)
+      (defalias #'smerge-diff-base-upper #'smerge-diff-base-mine)
+      (defalias #'smerge-diff-upper-lower #'smerge-diff-mine-other)
+      (defalias #'smerge-diff-base-lower #'smerge-diff-base-other)))
+
+  (defhydra +hydra-smerge (:hint nil
+                           :pre (smerge-mode 1)
+                           ;; Disable `smerge-mode' when quitting hydra if
+                           ;; no merge conflicts remain.
+                           :post (smerge-auto-leave))
+    "
+                                                    ╭────────┐
+  Movement   Keep           Diff              Other │ smerge │
+  ╭─────────────────────────────────────────────────┴────────╯
+     ^_g_^       [_b_] base       [_<_] upper/base    [_C_] Combine
+     ^_C-k_^     [_u_] upper      [_=_] upper/lower   [_r_] resolve
+     ^_k_ ↑^     [_l_] lower      [_>_] base/lower    [_R_] remove
+     ^_j_ ↓^     [_a_] all        [_H_] hightlight
+     ^_C-j_^     [_RET_] current  [_E_] ediff             ╭──────────
+     ^_G_^                                            │ [_q_] quit"
+    ("g" (progn (goto-char (point-min)) (smerge-next)))
+    ("G" (progn (goto-char (point-max)) (smerge-prev)))
+    ("C-j" smerge-next)
+    ("C-k" smerge-prev)
+    ("j" next-line)
+    ("k" previous-line)
+    ("b" smerge-keep-base)
+    ("u" smerge-keep-upper)
+    ("l" smerge-keep-lower)
+    ("a" smerge-keep-all)
+    ("RET" smerge-keep-current)
+    ("\C-m" smerge-keep-current)
+    ("<" smerge-diff-base-upper)
+    ("=" smerge-diff-upper-lower)
+    (">" smerge-diff-base-lower)
+    ("H" smerge-refine)
+    ("E" smerge-ediff)
+    ("C" smerge-combine-with-next)
+    ("r" smerge-resolve)
+    ("R" smerge-kill-current)
+    ("q" nil :color blue)))
+

modules/emacs/vc/packages.el

@@ -0,0 +1,7 @@
+;; -*- no-byte-compile: t; -*-
+;;; emacs/vc/packages.el
+
+(package! git-link)
+(package! git-timemachine)
+(package! gitconfig-mode)
+(package! gitignore-mode)