Extract neotree from feature/evil => tools/neotree

modules/tools/neotree/README.org

@@ -0,0 +1,7 @@
+* :evil neotree
+
+This module brings a side panel for browsing project files, inspired by vim's NERDTree.
+
+#+begin_quote
+Sure, there's dired and projectile, but sometimes I'd like a bird's eye view of a project.
+#+end_quote

modules/tools/neotree/autoload.el

@@ -0,0 +1,54 @@
+;;; tools/neotree/autoload.el
+
+;;;###autoload
+(defun +neotree/toggle ()
+  "Toggle the neotree window."
+  (interactive)
+  (let ((in-neotree (and (neo-global--window-exists-p)
+                         (window-live-p neo-global--buffer)
+                         (eq (current-buffer) neo-global--buffer)))
+        (path buffer-file-name))
+    (if in-neotree
+        (neotree-hide)
+      (let ((project-root (doom-project-root)))
+        (unless (and (neo-global--window-exists-p)
+                     (equal (file-truename (neo-global--with-buffer neo-buffer--start-node))
+                            (file-truename project-root)))
+          (neotree-dir project-root))
+        (neotree-find path project-root)))))
+
+;;;###autoload
+(defun +neotree/collapse-or-up ()
+  "Collapse an expanded directory node or go to the parent node."
+  (interactive)
+  (when-let (node (neo-buffer--get-filename-current-line))
+    (if (file-directory-p node)
+        (if (neo-buffer--expanded-node-p node)
+            (+neotree/collapse)
+          (neotree-select-up-node))
+      (neotree-select-up-node))))
+
+;;;###autoload
+(defun +neotree/collapse ()
+  "Collapse a neotree node."
+  (interactive)
+  (when-let (node (neo-buffer--get-filename-current-line))
+    (when (file-directory-p node)
+      (neo-buffer--set-expand node nil)
+      (neo-buffer--refresh t))
+    (when neo-auto-indent-point
+      (neo-point-auto-indent))))
+
+;;;###autoload
+(defun +neotree/expand-or-open ()
+  "Expand or open a neotree node."
+  (interactive)
+  (when-let (node (neo-buffer--get-filename-current-line))
+    (if (file-directory-p node)
+        (progn
+          (neo-buffer--set-expand node t)
+          (neo-buffer--refresh t)
+          (when neo-auto-indent-point
+            (forward-line)
+            (neo-point-auto-indent)))
+      (call-interactively 'neotree-enter))))

modules/tools/neotree/config.el

@@ -0,0 +1,37 @@
+;;; tools/neotree/config.el
+
+(def-package! neotree
+  :commands (neotree-show
+             neotree-hide
+             neotree-toggle
+             neotree-dir
+             neotree-find
+             neo-global--with-buffer
+             neo-global--window-exists-p)
+  :config
+  (setq neo-create-file-auto-open nil
+        neo-auto-indent-point nil
+        neo-autorefresh nil
+        neo-mode-line-type 'none
+        neo-window-width 25
+        neo-show-updir-line nil
+        neo-theme 'nerd ; fallback
+        neo-banner-message nil
+        neo-confirm-create-file #'off-p
+        neo-confirm-create-directory #'off-p
+        neo-show-hidden-files nil
+        neo-keymap-style 'concise
+        neo-hidden-regexp-list
+        '(;; vcs folders
+          "^\\.\\(git\\|hg\\|svn\\)$"
+          ;; compiled files
+          "\\.\\(pyc\\|o\\|elc\\|lock\\|css.map\\)$"
+          ;; generated files, caches or local pkgs
+          "^\\(node_modules\\|vendor\\|.\\(project\\|cask\\|yardoc\\|sass-cache\\)\\)$"
+          ;; org-mode folders
+          "^\\.\\(sync\\|export\\|attach\\)$"
+          "~$"
+          "^#.*#$"))
+
+  (when (bound-and-true-p winner-mode)
+    (push neo-buffer-name winner-boring-buffers)))

modules/tools/neotree/packages.el

@@ -0,0 +1,4 @@
+;; -*- no-byte-compile: t; -*-
+;;; tools/neotree/packages.el
+
+(package! neotree)